mirror of
https://github.com/pocoproject/poco.git
synced 2025-12-09 08:15:33 +01:00
8a4a2955d5
* chore(CppParser): 0, NULL --> nullptr * chore(Crypto): 0, NULL --> nullptr * chore(DNSSD): 0, NULL --> nullptr * chore(Encodings): 0, NULL --> nullptr * chore(CppUnit): Correct indentation. * chore(Foundation): 0, NULL --> nullptr * chore(CMake): Always warn about wrong nullptr usage when compiling with GCC or CLang * chore(Net): 0, NULL --> nullptr * chore(Foundation): 0, NULL --> nullptr * chore(Data): 0, NULL --> nullptr * chore(macOS): 0, NULL --> nullptr * chore(XML): 0, NULL --> nullptr * chore(Zip): 0, NULL --> nullptr * chore(Util): 0, NULL --> nullptr * chore(Net/NetSSL): 0, NULL --> nullptr * chore(Bonjour): 0, NULL --> nullptr * chore(MongoDB, Redis): 0, NULL --> nullptr * chore(Poco): 0, NULL --> nullptr * chore(Win32): 0, NULL --> nullptr * chore(CMake): Only warn about nullptr when verbose warnings are enabled. * Potential fix for code scanning alert no. 1634: Guarded Free Co-authored-by: Copilot Autofix powered by AI <62310815+github-advanced-security[bot]@users.noreply.github.com> * chore(Net): Fix warning reported by gitlab. * chore(gitlab CI): attempt to clean to gain disk space on the runner. * chore(gitlab CI): Run build with --parallel 4, correct docker cleanup. --------- Co-authored-by: Aleksandar Fabijanic <aleks-f@users.noreply.github.com> Co-authored-by: Copilot Autofix powered by AI <62310815+github-advanced-security[bot]@users.noreply.github.com>
94 lines
3.6 KiB
CMake
94 lines
3.6 KiB
CMake
# http://www.cmake.org/Wiki/CMake_Useful_Variables :
|
|
# CMAKE_BUILD_TYPE
|
|
# Choose the type of build. CMake has default flags for these:
|
|
#
|
|
# * None (CMAKE_C_FLAGS or CMAKE_CXX_FLAGS used)
|
|
# * Debug (CMAKE_C_FLAGS_DEBUG or CMAKE_CXX_FLAGS_DEBUG)
|
|
# * Release (CMAKE_C_FLAGS_RELEASE or CMAKE_CXX_FLAGS_RELEASE)
|
|
# * RelWithDebInfo (CMAKE_C_FLAGS_RELWITHDEBINFO or CMAKE_CXX_FLAGS_RELWITHDEBINFO
|
|
# * MinSizeRel (CMAKE_C_FLAGS_MINSIZEREL or CMAKE_CXX_FLAGS_MINSIZEREL)
|
|
|
|
# Setting CXX Flag /MD or /MT and POSTFIX values i.e MDd / MD / MTd / MT / d
|
|
# using CMake variable CMAKE_MSVC_RUNTIME_LIBRARY.
|
|
#
|
|
# For visual studio the library naming is as following:
|
|
# Dynamic libraries:
|
|
# - PocoX.dll for release library
|
|
# - PocoXd.dll for debug library
|
|
#
|
|
# Static libraries:
|
|
# - PocoXmd.lib for /MD release build
|
|
# - PocoXtmt.lib for /MT release build
|
|
#
|
|
# - PocoXmdd.lib for /MD debug build
|
|
# - PocoXmtd.lib for /MT debug build
|
|
|
|
if(BUILD_SHARED_LIBS)
|
|
add_compile_definitions(POCO_DLL)
|
|
else()
|
|
add_compile_definitions(POCO_STATIC)
|
|
endif()
|
|
|
|
if(MSVC)
|
|
if(POCO_MT)
|
|
set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
|
|
set(STATIC_POSTFIX "mt" CACHE STRING "Set static library postfix" FORCE)
|
|
else(POCO_MT)
|
|
set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>DLL")
|
|
set(STATIC_POSTFIX "md" CACHE STRING "Set static library postfix" FORCE)
|
|
endif(POCO_MT)
|
|
|
|
message(STATUS "MSVC runtime library: ${CMAKE_MSVC_RUNTIME_LIBRARY}")
|
|
|
|
if(POCO_SANITIZE_ASAN)
|
|
message(WARNING "Use POCO_SANITIZEFLAGS instead of POCO_SANITIZE_ASAN")
|
|
add_compile_options("/fsanitize=address")
|
|
endif()
|
|
|
|
else(MSVC)
|
|
# Other compilers then MSVC don't have a static STATIC_POSTFIX at the moment
|
|
set(STATIC_POSTFIX "" CACHE STRING "Set static library postfix" FORCE)
|
|
endif(MSVC)
|
|
|
|
if (DEFINED POCO_SANITIZEFLAGS AND NOT "${POCO_SANITIZEFLAGS}" STREQUAL "")
|
|
message(STATUS "Using sanitize flags: ${POCO_SANITIZEFLAGS}")
|
|
add_compile_options(${POCO_SANITIZEFLAGS})
|
|
add_link_options(${POCO_SANITIZEFLAGS})
|
|
endif()
|
|
|
|
if (ENABLE_COMPILER_WARNINGS)
|
|
message(STATUS "Enabling additional compiler warning flags.")
|
|
# Additional compiler-specific warning flags
|
|
if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
|
|
# using clang
|
|
add_compile_options(-Wall -Wextra -Wpedantic -Wno-unused-parameter)
|
|
# Warn when using 0 or NULL instead of nullptr constant
|
|
add_compile_options(-Wzero-as-null-pointer-constant)
|
|
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
|
|
# using GCC
|
|
add_compile_options(-Wall -Wextra -Wpedantic -Wno-unused-parameter)
|
|
# Warn when using 0 or NULL instead of nullptr constant
|
|
add_compile_options(-Wzero-as-null-pointer-constant)
|
|
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
|
|
# using Visual Studio C++
|
|
add_compile_options(/W4)
|
|
endif()
|
|
endif()
|
|
|
|
# Add a d postfix to the debug libraries
|
|
if(BUILD_SHARED_LIBS)
|
|
set(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "Set Debug library postfix" FORCE)
|
|
set(CMAKE_RELEASE_POSTFIX "" CACHE STRING "Set Release library postfix" FORCE)
|
|
set(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "Set MinSizeRel library postfix" FORCE)
|
|
set(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "Set RelWithDebInfo library postfix" FORCE)
|
|
else(BUILD_SHARED_LIBS)
|
|
set(CMAKE_DEBUG_POSTFIX "${STATIC_POSTFIX}d" CACHE STRING "Set Debug library postfix" FORCE)
|
|
set(CMAKE_RELEASE_POSTFIX "${STATIC_POSTFIX}" CACHE STRING "Set Release library postfix" FORCE)
|
|
set(CMAKE_MINSIZEREL_POSTFIX "${STATIC_POSTFIX}" CACHE STRING "Set MinSizeRel library postfix" FORCE)
|
|
set(CMAKE_RELWITHDEBINFO_POSTFIX "${STATIC_POSTFIX}" CACHE STRING "Set RelWithDebInfo library postfix" FORCE)
|
|
endif()
|
|
|
|
# OS Detection
|
|
include(CheckTypeSize)
|
|
find_package(Cygwin)
|