generic-library/poco
1
0
Fork 0
mirror of https://github.com/pocoproject/poco.git synced 2025-04-27 02:16:16 +02:00
Code Issues Projects Releases Wiki Activity

added runtests.cmd

Browse Source
This commit is contained in:
Günter Obiltschnig 2014-01-16 22:06:40 +01:00
parent 2f33fe2d7d
commit 0dc6a9ca3c
1 changed files with 68 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

68
build/script/runtests.cmd Normal file
View File

@ -0,0 +1,68 @@
@echo off
rem
rem $Id$
rem
rem A script for running the POCO testsuites.
rem
rem usage: runtests
rem
rem If the environment variable EXCLUDE_TESTS is set, containing
rem a space-separated list of project names (as found in the
rem components file), these tests will be skipped.
rem
setlocal EnableDelayedExpansion
set TESTRUNNER=TestSuite.exe
set TESTRUNNERARGS=/B
set runs=0
set failures=0
set failedTests=
set status=0
set excluded=0
for /f %%C in ('findstr /R "." components') do (
set excluded=0
for %%X in (%EXCLUDE_TESTS%) do (
if "%%X"=="%%C" (
set excluded=1
)
)
if !excluded!==0 (
if exist %%C (
if exist %%C\testsuite (
if exist %%C\testsuite\bin\%TESTRUNNER% (
echo.
echo.
echo ****************************************
echo *** %%C
echo ****************************************
echo.
set /a runs=!runs! + 1
set dir=%CD%
cd %%C\testsuite\bin
%TESTRUNNER% %TESTRUNNERARGS%
if !ERRORLEVEL! neq 0 (
set /a failures=!failures! + 1
set failedTests=!failedTests! %%C
set status=1
)
cd !dir!
)
)
)
)
)
echo.
echo.
echo !runs! runs, !failures! failed.
echo.
for %%F in (!failedTests!) do (
echo Failed: %%F
)
echo.
exit /b !status!