poco/Encodings/CMakeLists.txt

# Sources
file(GLOB SRCS_G "src/*.cpp")
POCO_SOURCES(SRCS Encodings ${SRCS_G})

# Headers
file(GLOB_RECURSE HDRS_G "include/*.h")
POCO_HEADERS(SRCS Encodings ${HDRS_G})

# Version Resource
if(MSVC AND BUILD_SHARED_LIBS)
	source_group("Resources" FILES ${PROJECT_SOURCE_DIR}/DLLVersion.rc)
	list(APPEND SRCS ${PROJECT_SOURCE_DIR}/DLLVersion.rc)
endif()

add_library(Encodings ${SRCS})
add_library(Poco::Encodings ALIAS Encodings)
set_target_properties(Encodings
	PROPERTIES
	VERSION ${SHARED_LIBRARY_VERSION} SOVERSION ${SHARED_LIBRARY_VERSION}
	OUTPUT_NAME PocoEncodings
	DEFINE_SYMBOL Encodings_EXPORTS
)

target_link_libraries(Encodings PUBLIC Poco::Foundation)
target_include_directories(Encodings
	PUBLIC
		$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
		$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
	PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/src
)

POCO_INSTALL(Encodings)
POCO_GENERATE_PACKAGE(Encodings)

if(ENABLE_TESTS)
	add_subdirectory(samples)
	add_subdirectory(testsuite)
endif()