##################################################################
#  Copyright (c) 2025 sanechips Technologies Co., Ltd.
#
#  Redistribution and use in source and binary forms, with or without
#  modification, are permitted provided that the following conditions
#  are met:
#    * Redistributions of source code must retain the above copyright
#      notice, this list of conditions and the following disclaimer.
#    * Redistributions in binary form must reproduce the above copyright
#      notice, this list of conditions and the following disclaimer in
#      the documentation and/or other materials provided with the
#      distribution.
#    * Neither the name of sanechips Corporation nor the names of its
#      contributors may be used to endorse or promote products derived
#      from this software without specific prior written permission.
#
#  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
#  "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
#  LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
#  A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
#  OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
#  SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
#  LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
#  DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
#  THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
#  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
#  OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
########################################################################

#if HAVE_RVV
.text
.align 2

.global gf_3vect_dot_prod_rvv
.type gf_3vect_dot_prod_rvv, @function

/* void gf_3vect_dot_prod_rvv(int len, int vlen, unsigned char *gftbls,
                              unsigned char **src, unsigned char **dest);
 */

/* arguments */
#define x_len a0  /* vector length */
#define x_vec a1  /* number of source vectors (ie. data blocks) */
#define x_tbl a2  /* gftbls */
#define x_src a3  /* src */
#define x_dest a4 /* dest */

/* local variables */
#define x_vec_i t1
#define x_ptr t2
#define x_pos t3
#define x_tbl1 t4
#define x_tbl2 t5
#define x_tbl3 t6
#define x_dest1 s0
#define x_dest2 s1
#define x_dest3 a5
#define t_offset a6

/* vectors */
#define v_src v1
#define v_src_lo v2
#define v_src_hi v3

#define v_dest1 v4
#define v_dest2 v5
#define v_dest3 v6

#define v_gft1_lo v8
#define v_gft1_hi v9
#define v_gft2_lo v10
#define v_gft2_hi v11
#define v_gft3_lo v12
#define v_gft3_hi v13

gf_3vect_dot_prod_rvv:
    /* less than 16 bytes, return_fail */
    li t0, 16
    blt x_len, t0, .return_fail

    /* save callee-saved registers */
    addi sp, sp, -16
    sd s0, 0(sp)
    sd s1, 8(sp)

    vsetvli a7, x0, e8, m1, ta, ma  /* Set vector length to maximum */
    li x_pos, 0
    slli x_vec, x_vec, 3

    slli t_offset, x_vec, 2
    ld x_dest1, 0(x_dest)
    ld x_dest2, 8(x_dest)
    ld x_dest3, 16(x_dest)

.Lloop_rvv_vl:
    /* check if we have processed all elements */
    bge x_pos, x_len, .return_pass

    /* Clear destination vectors */
    vmv.v.i v_dest1, 0
    vmv.v.i v_dest2, 0
    vmv.v.i v_dest3, 0

    /* Loop 2: x_vec, number of source vectors (ie. data blocks) */
    li x_vec_i, 0
    /* load source pointer */
    ld x_ptr, 0(x_src)

    /* Reset table pointers */
    mv x_tbl1, x_tbl
    add x_tbl2, x_tbl1, t_offset
    add x_tbl3, x_tbl2, t_offset

.Lloop_rvv_vl_vects:
    /* load source data */
    add x_ptr, x_ptr, x_pos
    vle8.v v_src, (x_ptr)

    /* Split 4-bit lo; 4-bit hi */
    vand.vi v_src_lo, v_src, 0x0F
    vsrl.vi v_src_hi, v_src, 4

    /* Load gf_table's */
    vle8.v v_gft1_lo, (x_tbl1)
    addi x_tbl1, x_tbl1, 16
    vle8.v v_gft1_hi, (x_tbl1)
    addi x_tbl1, x_tbl1, 16
    vle8.v v_gft2_lo, (x_tbl2)
    addi x_tbl2, x_tbl2, 16
    vle8.v v_gft2_hi, (x_tbl2)
    addi x_tbl2, x_tbl2, 16

    /* Move to next source vector */
    addi x_vec_i, x_vec_i, 8
    add t0, x_src, x_vec_i
    ld x_ptr, 0(t0)

    /* Load next gf_table's */
    vle8.v v_gft3_lo, (x_tbl3)
    addi x_tbl3, x_tbl3, 16
    vle8.v v_gft3_hi, (x_tbl3)
    addi x_tbl3, x_tbl3, 16

    /* dest 1 */
    vrgather.vv v26, v_gft1_lo, v_src_lo
    vrgather.vv v27, v_gft1_hi, v_src_hi
    vxor.vv v_dest1, v_dest1, v26
    vxor.vv v_dest1, v_dest1, v27

    /* dest 2 */
    vrgather.vv v26, v_gft2_lo, v_src_lo
    vrgather.vv v27, v_gft2_hi, v_src_hi
    vxor.vv v_dest2, v_dest2, v26
    vxor.vv v_dest2, v_dest2, v27

    /* dest 3 */
    vrgather.vv v26, v_gft3_lo, v_src_lo
    vrgather.vv v27, v_gft3_hi, v_src_hi
    vxor.vv v_dest3, v_dest3, v26
    vxor.vv v_dest3, v_dest3, v27

    /* Check if we have processed all vectors */
    blt x_vec_i, x_vec, .Lloop_rvv_vl_vects

    /* Store destination data */
    vse8.v v_dest1, (x_dest1)
    vse8.v v_dest2, (x_dest2)
    vse8.v v_dest3, (x_dest3)
    add x_dest1, x_dest1, a7
    add x_dest2, x_dest2, a7
    add x_dest3, x_dest3, a7

    add x_pos, x_pos, a7
    j .Lloop_rvv_vl

.return_pass:
    ld s0, 0(sp)
    ld s1, 8(sp)
    addi sp, sp, 16

    li a0, 0
    ret

.return_fail:
    li a0, 1
    ret

#endif
