eb6e2eac6c
This patch adds the working parts of r243503. The difference with this patch is that it doesn't include the HandleLLVMOptions.cmake file. git-svn-id: https://llvm.org/svn/llvm-project/libcxx/trunk@243698 91177308-0d34-0410-b5e6-96231b3b80d8
140 lines
5.1 KiB
CMake
140 lines
5.1 KiB
CMake
set(LIBCXX_LIB_CMAKEFILES_DIR "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}" PARENT_SCOPE)
|
|
|
|
# Get sources
|
|
file(GLOB LIBCXX_SOURCES ../src/*.cpp)
|
|
if(WIN32)
|
|
file(GLOB LIBCXX_WIN32_SOURCES ../src/support/win32/*.cpp)
|
|
list(APPEND LIBCXX_SOURCES ${LIBCXX_WIN32_SOURCES})
|
|
elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "SunOS")
|
|
file(GLOB LIBCXX_SOLARIS_SOURCES ../src/support/solaris/*.c)
|
|
list(APPEND LIBCXX_SOURCES ${LIBCXX_SOLARIS_SOURCES})
|
|
endif()
|
|
|
|
# Add all the headers to the project for IDEs.
|
|
if (MSVC_IDE OR XCODE)
|
|
file(GLOB_RECURSE LIBCXX_HEADERS ${CMAKE_CURRENT_SOURCE_DIR}/../include/*)
|
|
if(WIN32)
|
|
file( GLOB LIBCXX_WIN32_HEADERS ${CMAKE_CURRENT_SOURCE_DIR}/../include/support/win32/*.h)
|
|
list(APPEND LIBCXX_HEADERS ${LIBCXX_WIN32_HEADERS})
|
|
endif()
|
|
# Force them all into the headers dir on MSVC, otherwise they end up at
|
|
# project scope because they don't have extensions.
|
|
if (MSVC_IDE)
|
|
source_group("Header Files" FILES ${LIBCXX_HEADERS})
|
|
endif()
|
|
endif()
|
|
|
|
if (LIBCXX_ENABLE_SHARED)
|
|
add_library(cxx SHARED ${LIBCXX_SOURCES} ${LIBCXX_HEADERS})
|
|
else()
|
|
add_library(cxx STATIC ${LIBCXX_SOURCES} ${LIBCXX_HEADERS})
|
|
endif()
|
|
|
|
if (DEFINED LIBCXX_CXX_ABI_DEPS)
|
|
add_dependencies(cxx LIBCXX_CXX_ABI_DEPS)
|
|
endif()
|
|
|
|
#if LIBCXX_CXX_ABI_LIBRARY_PATH is defined we want to add it to the search path.
|
|
add_link_flags_if(LIBCXX_CXX_ABI_LIBRARY_PATH "-L${LIBCXX_CXX_ABI_LIBRARY_PATH}")
|
|
|
|
add_library_flags_if(LIBCXX_COVERAGE_LIBRARY "${LIBCXX_COVERAGE_LIBRARY}")
|
|
|
|
add_library_flags_if(LIBCXX_ENABLE_STATIC_ABI_LIBRARY "-Wl,--whole-archive" "-Wl,-Bstatic")
|
|
add_library_flags("${LIBCXX_CXX_ABI_LIBRARY}")
|
|
add_library_flags_if(LIBCXX_ENABLE_STATIC_ABI_LIBRARY "-Wl,-Bdynamic" "-Wl,--no-whole-archive")
|
|
|
|
if (APPLE AND LLVM_USE_SANITIZER)
|
|
if ("${LLVM_USE_SANITIZER}" STREQUAL "Address")
|
|
set(LIBFILE "libclang_rt.asan_osx_dynamic.dylib")
|
|
elseif("${LLVM_USE_SANITIZER}" STREQUAL "Undefined")
|
|
set(LIBFILE "libclang_rt.ubsan_osx_dynamic.dylib")
|
|
else()
|
|
message(WARNING "LLVM_USE_SANITIZER=${LLVM_USE_SANITIZER} is not supported on OS X")
|
|
endif()
|
|
if (LIBFILE)
|
|
execute_process(COMMAND ${CMAKE_CXX_COMPILER} -print-file-name=lib OUTPUT_VARIABLE LIBDIR RESULT_VARIABLE Result)
|
|
if (NOT ${Result} EQUAL "0")
|
|
message(FATAL "Failed to find library resource directory")
|
|
endif()
|
|
string(STRIP "${LIBDIR}" LIBDIR)
|
|
set(LIBDIR "${LIBDIR}/darwin/")
|
|
if (NOT IS_DIRECTORY "${LIBDIR}")
|
|
message(FATAL_ERROR "Cannot find compiler-rt directory on OS X required for LLVM_USE_SANITIZER")
|
|
endif()
|
|
set(LIBCXX_SANITIZER_LIBRARY "${LIBDIR}/${LIBFILE}")
|
|
set(LIBCXX_SANITIZER_LIBRARY "${LIBCXX_SANITIZER_LIBRARY}" PARENT_SCOPE)
|
|
message(STATUS "Manually linking compiler-rt library: ${LIBCXX_SANITIZER_LIBRARY}")
|
|
add_library_flags("${LIBCXX_SANITIZER_LIBRARY}")
|
|
add_link_flags("-Wl,-rpath,${LIBDIR}")
|
|
endif()
|
|
endif()
|
|
|
|
# Generate library list.
|
|
add_library_flags_if(LIBCXX_HAS_PTHREAD_LIB pthread)
|
|
add_library_flags_if(LIBCXX_HAS_C_LIB c)
|
|
add_library_flags_if(LIBCXX_HAS_M_LIB m)
|
|
add_library_flags_if(LIBCXX_HAS_RT_LIB rt)
|
|
add_library_flags_if(LIBCXX_HAS_GCC_S_LIB gcc_s)
|
|
|
|
# Setup flags.
|
|
add_flags_if_supported(-fPIC)
|
|
add_link_flags_if_supported(-nodefaultlibs)
|
|
|
|
if ( APPLE AND (LIBCXX_CXX_ABI_LIBNAME STREQUAL "libcxxabi" OR
|
|
LIBCXX_CXX_ABI_LIBNAME STREQUAL "none"))
|
|
if (NOT DEFINED LIBCXX_LIBCPPABI_VERSION)
|
|
set(LIBCXX_LIBCPPABI_VERSION "2")
|
|
endif()
|
|
|
|
if ( CMAKE_OSX_DEPLOYMENT_TARGET STREQUAL "10.6" )
|
|
add_definitions(-D__STRICT_ANSI__)
|
|
add_link_flags(
|
|
"-compatibility_version 1"
|
|
"-current_version 1"
|
|
"-install_name /usr/lib/libc++.1.dylib"
|
|
"-Wl,-reexport_library,/usr/lib/libc++abi.dylib"
|
|
"-Wl,-unexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++unexp.exp"
|
|
"/usr/lib/libSystem.B.dylib")
|
|
else()
|
|
if ( ${CMAKE_OSX_SYSROOT} )
|
|
list(FIND ${CMAKE_OSX_ARCHITECTURES} "armv7" OSX_HAS_ARMV7)
|
|
if (OSX_HAS_ARMV7)
|
|
set(OSX_RE_EXPORT_LINE
|
|
"${CMAKE_OSX_SYSROOT}/usr/lib/libc++abi.dylib"
|
|
"-Wl,-reexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++sjlj-abi.exp")
|
|
else()
|
|
set(OSX_RE_EXPORT_LINE
|
|
"-Wl,-reexport_library,${CMAKE_OSX_SYSROOT}/usr/lib/libc++abi.dylib")
|
|
endif()
|
|
else()
|
|
set (OSX_RE_EXPORT_LINE "/usr/lib/libc++abi.dylib -Wl,-reexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++abi${LIBCXX_LIBCPPABI_VERSION}.exp")
|
|
endif()
|
|
|
|
add_link_flags(
|
|
"-compatibility_version 1"
|
|
"-install_name /usr/lib/libc++.1.dylib"
|
|
"-Wl,-unexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++unexp.exp"
|
|
"${OSX_RE_EXPORT_LINE}"
|
|
"-Wl,-force_symbols_not_weak_list,${CMAKE_CURRENT_SOURCE_DIR}/notweak.exp"
|
|
"-Wl,-force_symbols_weak_list,${CMAKE_CURRENT_SOURCE_DIR}/weak.exp")
|
|
endif()
|
|
endif()
|
|
|
|
target_link_libraries(cxx ${LIBCXX_LIBRARIES})
|
|
split_list(LIBCXX_COMPILE_FLAGS)
|
|
split_list(LIBCXX_LINK_FLAGS)
|
|
|
|
set_target_properties(cxx
|
|
PROPERTIES
|
|
COMPILE_FLAGS "${LIBCXX_COMPILE_FLAGS}"
|
|
LINK_FLAGS "${LIBCXX_LINK_FLAGS}"
|
|
OUTPUT_NAME "c++"
|
|
VERSION "1.0"
|
|
SOVERSION "1"
|
|
)
|
|
|
|
install(TARGETS cxx
|
|
LIBRARY DESTINATION lib${LIBCXX_LIBDIR_SUFFIX}
|
|
ARCHIVE DESTINATION lib${LIBCXX_LIBDIR_SUFFIX}
|
|
)
|