d74dee9255
This change was reverted in r243550 because it broke clang-format builds (see PR24306). This patch recommits a fixed version of the original. git-svn-id: https://llvm.org/svn/llvm-project/libcxx/trunk@243574 91177308-0d34-0410-b5e6-96231b3b80d8
247 lines
10 KiB
CMake
247 lines
10 KiB
CMake
# See www/CMake.html for instructions on how to build libcxx with CMake.
|
|
|
|
#===============================================================================
|
|
# Setup Project
|
|
#===============================================================================
|
|
cmake_minimum_required(VERSION 2.8)
|
|
|
|
if(POLICY CMP0042)
|
|
cmake_policy(SET CMP0042 NEW) # Set MACOSX_RPATH=YES by default
|
|
endif()
|
|
if(POLICY CMP0022)
|
|
cmake_policy(SET CMP0022 NEW) # Required when interacting with LLVM and Clang
|
|
endif()
|
|
|
|
project(libcxx CXX C)
|
|
|
|
set(PACKAGE_NAME libcxx)
|
|
set(PACKAGE_VERSION trunk-svn)
|
|
set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
|
|
set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
|
|
|
|
# Add path for custom modules
|
|
set(CMAKE_MODULE_PATH
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/cmake"
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
|
|
${CMAKE_MODULE_PATH}
|
|
)
|
|
|
|
# Require out of source build.
|
|
include(MacroEnsureOutOfSourceBuild)
|
|
MACRO_ENSURE_OUT_OF_SOURCE_BUILD(
|
|
"${PROJECT_NAME} requires an out of source build. Please create a separate
|
|
build directory and run 'cmake /path/to/${PROJECT_NAME} [options]' there."
|
|
)
|
|
|
|
# Find the required bits of LLVM
|
|
include(FindLLVM)
|
|
|
|
#===============================================================================
|
|
# Setup CMake Options
|
|
#===============================================================================
|
|
|
|
# Basic options ---------------------------------------------------------------
|
|
option(LIBCXX_ENABLE_ASSERTIONS "Enable assertions independent of build mode." ON)
|
|
option(LIBCXX_ENABLE_SHARED "Build libc++ as a shared library." ON)
|
|
|
|
set(LIBCXX_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}" CACHE STRING
|
|
"Define suffix of library directory name (32/64)")
|
|
option(LIBCXX_INSTALL_HEADERS "Install the libc++ headers." ON)
|
|
option(LIBCXX_INSTALL_SUPPORT_HEADERS "Install libc++ support headers." ON)
|
|
|
|
# ABI Library options ---------------------------------------------------------
|
|
set(LIBCXX_CXX_ABI "${LIBCXX_CXX_ABI}" CACHE STRING
|
|
"Specify C++ ABI library to use." FORCE)
|
|
set(CXXABIS none libcxxabi libcxxrt libstdc++ libsupc++)
|
|
set_property(CACHE LIBCXX_CXX_ABI PROPERTY STRINGS ;${CXXABIS})
|
|
|
|
option(LIBCXX_ENABLE_STATIC_ABI_LIBRARY "Statically link the ABI library" OFF)
|
|
|
|
# Build libc++abi with libunwind. We need this option to determine whether to
|
|
# link with libunwind or libgcc_s while running the test cases.
|
|
option(LIBCXXABI_USE_LLVM_UNWINDER "Build and use the LLVM unwinder." OFF)
|
|
|
|
# Target options --------------------------------------------------------------
|
|
option(LIBCXX_BUILD_32_BITS "Build 32 bit libc++." OFF)
|
|
set(LIBCXX_SYSROOT "" CACHE STRING "Use alternate sysroot.")
|
|
set(LIBCXX_GCC_TOOLCHAIN "" CACHE STRING "Use alternate GCC toolchain.")
|
|
|
|
# Feature options -------------------------------------------------------------
|
|
option(LIBCXX_ENABLE_EXCEPTIONS "Use exceptions." ON)
|
|
option(LIBCXX_ENABLE_RTTI "Use run time type information." ON)
|
|
option(LIBCXX_ENABLE_GLOBAL_FILESYSTEM_NAMESPACE "Build libc++ with support for the global filesystem namespace." ON)
|
|
option(LIBCXX_ENABLE_STDIN "Build libc++ with support for stdin/std::cin." ON)
|
|
option(LIBCXX_ENABLE_STDOUT "Build libc++ with support for stdout/std::cout." ON)
|
|
option(LIBCXX_ENABLE_THREADS "Build libc++ with support for threads." ON)
|
|
option(LIBCXX_ENABLE_THREAD_UNSAFE_C_FUNCTIONS "Build libc++ with support for thread-unsafe C functions" ON)
|
|
option(LIBCXX_ENABLE_MONOTONIC_CLOCK
|
|
"Build libc++ with support for a monotonic clock.
|
|
This option may only be used when LIBCXX_ENABLE_THREADS=OFF." ON)
|
|
|
|
# Misc options ----------------------------------------------------------------
|
|
option(LIBCXX_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
|
|
option(LIBCXX_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
|
|
|
|
option(LIBCXX_GENERATE_COVERAGE "Enable generating code coverage." OFF)
|
|
set(LIBCXX_COVERAGE_LIBRARY "" CACHE STRING
|
|
"The Profile-rt library used to build with code coverage")
|
|
|
|
#===============================================================================
|
|
# Check option configurations
|
|
#===============================================================================
|
|
|
|
# Ensure LIBCXX_ENABLE_MONOTONIC_CLOCK is set to ON only when
|
|
# LIBCXX_ENABLE_THREADS is on.
|
|
if(LIBCXX_ENABLE_THREADS AND NOT LIBCXX_ENABLE_MONOTONIC_CLOCK)
|
|
message(FATAL_ERROR "LIBCXX_ENABLE_MONOTONIC_CLOCK can only be set to OFF"
|
|
" when LIBCXX_ENABLE_THREADS is also set to OFF.")
|
|
endif()
|
|
|
|
# Ensure LLVM_USE_SANITIZER is not specified when LIBCXX_GENERATE_COVERAGE
|
|
# is ON.
|
|
if (LLVM_USE_SANITIZER AND LIBCXX_GENERATE_COVERAGE)
|
|
message(FATAL_ERROR "LLVM_USE_SANITIZER cannot be used with LIBCXX_GENERATE_COVERAGE")
|
|
endif()
|
|
|
|
# Set LIBCXX_BUILD_32_BITS to (LIBCXX_BUILD_32_BITS OR LLVM_BUILD_32_BITS)
|
|
# and check that we can build with 32 bits if requested.
|
|
if (CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32)
|
|
if (LIBCXX_BUILD_32_BITS OR LLVM_BUILD_32_BITS)
|
|
if (NOT LLVM_BUILD_32_BITS) # Don't duplicate the output from LLVM
|
|
message(STATUS "Building 32 bits executables and libraries.")
|
|
endif()
|
|
set(LIBCXX_BUILD_32_BITS ON CACHE BOOL "" FORCE)
|
|
endif()
|
|
elseif(LIBCXX_BUILD_32_BITS)
|
|
message(FATAL_ERROR "LIBCXX_BUILD_32_BITS=ON is not supported on this platform.")
|
|
endif()
|
|
|
|
# Check that this option is not enabled on Apple and emit a usage warning.
|
|
if (LIBCXX_ENABLE_STATIC_ABI_LIBRARY)
|
|
if (APPLE)
|
|
message(FATAL_ERROR "LIBCXX_ENABLE_STATIC_ABI_LIBRARY is not supported on OS X")
|
|
else()
|
|
message(WARNING "LIBCXX_ENABLE_STATIC_ABI_LIBRARY is an experimental option")
|
|
endif()
|
|
endif()
|
|
|
|
#===============================================================================
|
|
# Configure System
|
|
#===============================================================================
|
|
|
|
set(LIBCXX_COMPILER ${CMAKE_CXX_COMPILER})
|
|
set(LIBCXX_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
|
|
set(LIBCXX_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
|
|
set(LIBCXX_LIBRARY_DIR ${CMAKE_BINARY_DIR}/lib${LIBCXX_LIBDIR_SUFFIX})
|
|
|
|
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LIBCXX_LIBRARY_DIR})
|
|
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LIBCXX_LIBRARY_DIR})
|
|
|
|
# Declare libc++ configuration variables.
|
|
# They are intended for use as follows:
|
|
# LIBCXX_CXX_FLAGS: General flags for both the compiler and linker.
|
|
# LIBCXX_COMPILE_FLAGS: Compile only flags.
|
|
# LIBCXX_LINK_FLAGS: Linker only flags.
|
|
set(LIBCXX_COMPILE_FLAGS "")
|
|
set(LIBCXX_LINK_FLAGS "")
|
|
set(LIBCXX_LIBRARIES "")
|
|
|
|
# Configure compiler.
|
|
include(config-ix)
|
|
|
|
# Configure coverage options.
|
|
if (LIBCXX_GENERATE_COVERAGE)
|
|
include(CodeCoverage)
|
|
set(CMAKE_BUILD_TYPE "COVERAGE" CACHE STRING "" FORCE)
|
|
endif()
|
|
|
|
string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
|
|
|
|
#===============================================================================
|
|
# Setup Compiler Flags
|
|
#===============================================================================
|
|
|
|
include(HandleLibCXXABI) # Steup the ABI library flags
|
|
|
|
# Include macros for adding and removing libc++ flags.
|
|
include(HandleLibcxxFlags)
|
|
|
|
# Remove flags that may have snuck in.
|
|
remove_flags(-DNDEBUG -UNDEBUG -D_DEBUG
|
|
-stdlib=libc++ -stdlib=libstdc++ -lc++abi -m32)
|
|
|
|
# Required flags ==============================================================
|
|
add_compile_flags_if_supported(-std=c++11)
|
|
if (NOT MSVC AND NOT LIBCXX_SUPPORTS_STD_EQ_CXX11_FLAG)
|
|
message(FATAL_ERROR "C++11 is required but the compiler does not support -std=c++11")
|
|
endif()
|
|
|
|
# On all systems the system c++ standard library headers need to be excluded.
|
|
# MSVC only has -X, which disables all default includes; including the crt.
|
|
# Thus, we do nothing and hope we don't accidentally include any of the C++
|
|
# headers
|
|
add_compile_flags_if_supported(-nostdinc++)
|
|
|
|
# Target flags ================================================================
|
|
add_flags_if(LIBCXX_BUILD_32_BITS -m32)
|
|
add_flags_if(LIBCXX_TARGET_TRIPLE "-target ${LIBCXX_TARGET_TRIPLE}")
|
|
add_flags_if(LIBCXX_SYSROOT "--sysroot ${LIBCXX_SYSROOT}")
|
|
add_flags_if(LIBCXX_GCC_TOOLCHAIN "-gcc-toolchain ${LIBCXX_GCC_TOOLCHAIN}")
|
|
|
|
# Warning flags ===============================================================
|
|
add_definitions(-D_LIBCPP_HAS_NO_PRAGMA_SYSTEM_HEADER)
|
|
add_compile_flags_if_supported(
|
|
-Wall -W -Wwrite-strings
|
|
-Wno-unused-parameter -Wno-long-long
|
|
-Werror=return-type)
|
|
if (LIBCXX_ENABLE_WERROR)
|
|
add_compile_flags_if_supported(-Werror)
|
|
add_compile_flags_if_supported(-WX)
|
|
endif()
|
|
if (LIBCXX_ENABLE_PEDANTIC)
|
|
add_compile_flags_if_supported(-pedantic)
|
|
endif()
|
|
|
|
# Exception flags =============================================================
|
|
if (LIBCXX_ENABLE_EXCEPTIONS)
|
|
# Catches C++ exceptions only and tells the compiler to assume that extern C
|
|
# functions never throw a C++ exception.
|
|
add_compile_flags_if_supported(-EHsc)
|
|
else()
|
|
add_definitions(-D_LIBCPP_NO_EXCEPTIONS)
|
|
add_compile_flags_if_supported(-EHs- -EHa-)
|
|
add_compile_flags_if_supported(-fno-exceptions)
|
|
endif()
|
|
|
|
# RTTI flags ==================================================================
|
|
if (NOT LIBCXX_ENABLE_RTTI)
|
|
add_definitions(-D_LIBCPP_NO_RTTI)
|
|
add_compile_flags_if_supported(-GR-)
|
|
add_compile_flags_if_supported(-fno-rtti)
|
|
endif()
|
|
|
|
# Assertion flags =============================================================
|
|
define_if(LIBCXX_ENABLE_ASSERTIONS -UNDEBUG)
|
|
define_if_not(LIBCXX_ENABLE_ASSERTIONS -DNDEBUG)
|
|
if (LIBCXX_ENABLE_ASSERTIONS)
|
|
# MSVC doesn't like _DEBUG on release builds. See PR 4379.
|
|
define_if_not(MSVC -D_DEBUG)
|
|
endif()
|
|
|
|
# Feature flags ===============================================================
|
|
define_if(MSVC -D_CRT_SECURE_NO_WARNINGS)
|
|
define_if_not(LIBCXX_ENABLE_GLOBAL_FILESYSTEM_NAMESPACE -D_LIBCPP_HAS_NO_GLOBAL_FILESYSTEM_NAMESPACE)
|
|
define_if_not(LIBCXX_ENABLE_STDIN -D_LIBCPP_HAS_NO_STDIN)
|
|
define_if_not(LIBCXX_ENABLE_STDOUT -D_LIBCPP_HAS_NO_STDOUT)
|
|
define_if_not(LIBCXX_ENABLE_THREADS -D_LIBCPP_HAS_NO_THREADS)
|
|
define_if_not(LIBCXX_ENABLE_MONOTONIC_CLOCK -D_LIBCPP_HAS_NO_MONOTONIC_CLOCK)
|
|
define_if_not(LIBCXX_ENABLE_THREAD_UNSAFE_C_FUNCTIONS -D_LIBCPP_HAS_NO_THREAD_UNSAFE_C_FUNCTIONS)
|
|
|
|
#===============================================================================
|
|
# Setup Source Code And Tests
|
|
#===============================================================================
|
|
include_directories(include)
|
|
add_subdirectory(include)
|
|
add_subdirectory(lib)
|
|
add_subdirectory(test)
|