15a0456d0b
__set_errno returns -1 exactly so that callers don't need to bother. The other architectures were already taking advantage of this, but no one had ever fixed x86 and x86_64. Change-Id: Ie131494be664f6c4a1bbf8c61bbbed58eac56122
51 lines
1.1 KiB
ArmAsm
51 lines
1.1 KiB
ArmAsm
/*
|
|
* Generic syscall call.
|
|
* Upon entry:
|
|
* %eax: system call number - caller save
|
|
* %ebx: arg0 to system call - callee save
|
|
* %ecx: arg1 - caller save
|
|
* %edx: arg2 - caller save
|
|
* %esi: arg3 - callee save
|
|
* %edi: arg4 - callee save
|
|
* %ebp: arg5 - callee save
|
|
*/
|
|
|
|
#include <private/bionic_asm.h>
|
|
|
|
ENTRY(syscall)
|
|
# Push the callee save registers.
|
|
push %ebx
|
|
push %esi
|
|
push %edi
|
|
push %ebp
|
|
|
|
# Load all the arguments from the calling frame.
|
|
# (Not all will be valid, depending on the syscall.)
|
|
mov 20(%esp),%eax
|
|
mov 24(%esp),%ebx
|
|
mov 28(%esp),%ecx
|
|
mov 32(%esp),%edx
|
|
mov 36(%esp),%esi
|
|
mov 40(%esp),%edi
|
|
mov 44(%esp),%ebp
|
|
|
|
# Make the system call.
|
|
int $0x80
|
|
|
|
# Error?
|
|
cmpl $-MAX_ERRNO, %eax
|
|
jb 1f
|
|
# Yes, so set errno.
|
|
negl %eax
|
|
pushl %eax
|
|
call __set_errno
|
|
addl $4, %esp
|
|
1:
|
|
# Restore the callee save registers.
|
|
pop %ebp
|
|
pop %edi
|
|
pop %esi
|
|
pop %ebx
|
|
ret
|
|
END(syscall)
|