eb847bc866
The x86_64 build was failing because clone.S had a call to __thread_entry which was being added to a different intermediate .a on the way to making libc.so, and the linker couldn't guarantee statically that such a relocation would be possible. ld: error: out/target/product/generic_x86_64/obj/STATIC_LIBRARIES/libc_common_intermediates/libc_common.a(clone.o): requires dynamic R_X86_64_PC32 reloc against '__thread_entry' which may overflow at runtime; recompile with -fPIC This patch addresses that by ensuring that the caller and callee end up in the same intermediate .a. While I'm here, I've tried to clean up some of the mess that led to this situation too. In particular, this removes libc/private/ from the default include path (except for the DNS code), and splits out the DNS code into its own library (since it's a weird special case of upstream NetBSD code that's diverged so heavily it's unlikely ever to get back in sync). There's more cleanup of the DNS situation possible, but this is definitely a step in the right direction, and it's more than enough to get x86_64 building cleanly. Change-Id: I00425a7245b7a2573df16cc38798187d0729e7c4
134 lines
4.1 KiB
ArmAsm
134 lines
4.1 KiB
ArmAsm
/*
|
|
* Copyright (C) 2008 The Android Open Source Project
|
|
* All rights reserved.
|
|
*
|
|
* Redistribution and use in source and binary forms, with or without
|
|
* modification, are permitted provided that the following conditions
|
|
* are met:
|
|
* * Redistributions of source code must retain the above copyright
|
|
* notice, this list of conditions and the following disclaimer.
|
|
* * Redistributions in binary form must reproduce the above copyright
|
|
* notice, this list of conditions and the following disclaimer in
|
|
* the documentation and/or other materials provided with the
|
|
* distribution.
|
|
*
|
|
* THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
|
|
* "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
|
|
* LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
|
|
* FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
|
|
* COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
|
|
* INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
|
|
* BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
|
|
* OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
|
|
* AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
|
|
* OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
|
|
* OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
|
|
* SUCH DAMAGE.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
#include "private/libc_events.h"
|
|
|
|
/*
|
|
* Optimized memset() for ARM.
|
|
*
|
|
* memset() returns its first argument.
|
|
*/
|
|
|
|
ENTRY(__memset_chk)
|
|
cmp r2, r3
|
|
bls done
|
|
|
|
ldr r0, error_message
|
|
ldr r1, error_code
|
|
1:
|
|
add r0, pc
|
|
bl __fortify_chk_fail
|
|
error_code:
|
|
.word BIONIC_EVENT_MEMSET_BUFFER_OVERFLOW
|
|
error_message:
|
|
.word error_string-(1b+8)
|
|
|
|
END(__memset_chk)
|
|
|
|
ENTRY(bzero)
|
|
mov r2, r1
|
|
mov r1, #0
|
|
|
|
done:
|
|
// Fall through to memset...
|
|
END(bzero)
|
|
|
|
ENTRY(memset)
|
|
/* compute the offset to align the destination
|
|
* offset = (4-(src&3))&3 = -src & 3
|
|
*/
|
|
.save {r0, r4-r7, lr}
|
|
stmfd sp!, {r0, r4-r7, lr}
|
|
rsb r3, r0, #0
|
|
ands r3, r3, #3
|
|
cmp r3, r2
|
|
movhi r3, r2
|
|
|
|
/* splat r1 */
|
|
mov r1, r1, lsl #24
|
|
orr r1, r1, r1, lsr #8
|
|
orr r1, r1, r1, lsr #16
|
|
|
|
movs r12, r3, lsl #31
|
|
strcsb r1, [r0], #1 /* can't use strh (alignment unknown) */
|
|
strcsb r1, [r0], #1
|
|
strmib r1, [r0], #1
|
|
subs r2, r2, r3
|
|
ldmlsfd sp!, {r0, r4-r7, lr} /* return */
|
|
bxls lr
|
|
|
|
/* align the destination to a cache-line */
|
|
mov r12, r1
|
|
mov lr, r1
|
|
mov r4, r1
|
|
mov r5, r1
|
|
mov r6, r1
|
|
mov r7, r1
|
|
|
|
rsb r3, r0, #0
|
|
ands r3, r3, #0x1C
|
|
beq 3f
|
|
cmp r3, r2
|
|
andhi r3, r2, #0x1C
|
|
sub r2, r2, r3
|
|
|
|
/* conditionally writes 0 to 7 words (length in r3) */
|
|
movs r3, r3, lsl #28
|
|
stmcsia r0!, {r1, lr}
|
|
stmcsia r0!, {r1, lr}
|
|
stmmiia r0!, {r1, lr}
|
|
movs r3, r3, lsl #2
|
|
strcs r1, [r0], #4
|
|
|
|
3:
|
|
subs r2, r2, #32
|
|
mov r3, r1
|
|
bmi 2f
|
|
1: subs r2, r2, #32
|
|
stmia r0!, {r1,r3,r4,r5,r6,r7,r12,lr}
|
|
bhs 1b
|
|
2: add r2, r2, #32
|
|
|
|
/* conditionally stores 0 to 31 bytes */
|
|
movs r2, r2, lsl #28
|
|
stmcsia r0!, {r1,r3,r12,lr}
|
|
stmmiia r0!, {r1, lr}
|
|
movs r2, r2, lsl #2
|
|
strcs r1, [r0], #4
|
|
strmih r1, [r0], #2
|
|
movs r2, r2, lsl #2
|
|
strcsb r1, [r0]
|
|
ldmfd sp!, {r0, r4-r7, lr}
|
|
bx lr
|
|
END(memset)
|
|
|
|
.data
|
|
error_string:
|
|
.string "memset prevented write past end of buffer"
|